Below are several sample FOCUS reports that join data from the LV file to other leave files.
|
LV and LB
|
FOC1070
|
State Service and Leave Balances
|
|
LV and LD
|
FOC1071
|
Establishment, Wait Periods and Non-standard Accrual Rates
|
|
LV and LS
|
FOC1072
|
State Service Transaction Information
|
|
LV and LH
|
FOC1073
|
Employment History Transaction Information
|
|
LV and LR
|
FOC1074
|
Leave Transaction Information
|
|
LV and LR
|
FOC1075
|
Family Leave Use
|
FOCEXEC: FOC1070
The following program uses the join between the LV and LB files to print a leave detail report.
EX JLVLB
DEFINE FILE LV ADD
TXT/A10='STATE SVC: ';
END
TABLE FILE LV
PRINT LB:LT AS 'LVE,BEN,ID'
LB:BEGBAL AS 'BEG,BAL'
LB:TOTUSED AS 'TOTAL,USED'
LB:ENDBAL AS 'ENDING,BAL'
LB:TOTCR AS 'TOT,CR,AMT'
LB:FLSACTO AS 'TOT,FLSA,AMT'
LB:REGLCTO AS 'TOT,REG,CTO"
BY LV:SSA AS '' skip-line
BY LV:wNAME AS ''
BY TXT AS ''
BY LV:SSMOBAL AS '' FOLD-LINE
BY LB:LVPRD AS 'LVE,PRD,DATE'
HEADING CENTER
"THE CALIFORNIA STATE UNIVERSITY"
"STATE SERVICE AND LEAVE BALANCES"
"common FOCEXEC(FOC1070)"
"REPORT run on &DATE"
END
The following is only an excerpt from the actual report.
THE CALIFORNIA STATE UNIVERSITY
STATE SERVICE AND LEAVE BALANCES
COMMON FOCEXEC(FOC1070)
RUN ON 05/03/2002
LVE LVE TOT TOT TOT
PRD BEN BEG TOTAL ENDING CR FLSA REG
DATE ID BAL USED BAL AMT CTO CTO
---- --- --- ----- ----- --- ---- ---
999-99-2222 SMITH STATE SVC: 6
200201 VA 73.668 3.000 70.668 12.667 .000 .000
SL 743.000 1.000 742.000 8.000 .000 .000
PH .000 .000 1.000 1.000 .000 .000
CT 24.000 11.000 36.000 22.500 22.500 .000
FL .000 .000 .000 .000 .000 .000
200202 VA 83.335 31.000 52.335 12.667 .000 .000
SL 750.000 .000 750.000 8.000 .000 .000
CT 36.000 .000 43.500 7.500 7.500 .000
FOCEXEC: FOC1071
This program prints the establishment, waiting periods and non-standard accrual rates by leave period for your employees. It uses the join between the LV file (Employee Specific Information) and the LD file to retrieve employee last name. The ALL. parameter is used to include parent segment instances that lack descendants.
EX JLVLD
DEFINE FILE LV ADD
TXT/A10='STATE SVC:';
END
TABLE FILE LV
PRINT ALL.LD:LT
ALL.LD:ENDBAL
ALL.LD:ESTDATE
ALL.LD:ENDDATE
ALL.LD:NONSTDB
ALL.LD:NONSTDE
ALL.LD:NONSTDRT
ALL.LD:WAITBEG
ALL.LD:WAITEND
BY LV:SSA AS '' IN +10
BY LV:LASTNAME AS ''
BY TXT AS ''
BY LV:SSMOBAL AS '' FOLD-LINE
HEADING CENTER
"THE CALIFORNIA STATE UNIVERSITY"
"ESTABLISHMENT, WAIT PERIODS AND NON-STANDARD ACCRUAL RATES"
"FOCEXEC(FOC1071)"
"REPORT RUN ON &DATE"
END
The following is only an excerpt from the actual report.
THE CALIFORNIA STATE UNIVERSITY
ESTABLISHMENT, WAIT PERIODS AND NON-STANDARD ACCRUAL RATES
FOCEXEC(FOC1071)
REPORT RUN ON 99/99/99
WAIT WAIT
BEN LEAVE EST END NON STD NON STD NON STD BEG END
ID BALANCE DATE DATE BEG DATE END DATE ACCR RATE DATE DATE
--- ------- ---- ---- -------- -------- --------- ---- ----
000-00-0343 ELEPHANT STATE SVC: 8
VA 45.000 200101 999999 200101 999999 24.000 . .
SL 624.000 199509 999999 200102 999999 20.000 . .
000-00-1147 DEER STATE SVC: 41
VA 129.600 199909 999999 199909 999999 16.000 . .
000-00-2072 KANGAROO STATE SVC: 54
SL 14.400 200009 200105 200102 200105 10.667 . .
FOCEXEC: FOC1072
The report below prints state service transaction information by leave period for your employees. It uses the join between the LV file (Employee Specific Information) and the LS file to retrieve employee last name.
EX JLVLS
DEFINE FILE LV ADD
TXT/A10='STATE SVC:';
END
TABLE FILE LV
PRINT LS:TRANTYP
LS:LPSNSEQ
LS:LVPOSIT
LS:POST
LS:VOIDIND
LS:VOID
LS:SRCEID
LS:ORIGIN
LS:FRACAMT
LS:HRSWRK
LS:DAYSWRK
LS:MTHAMT
LS:RULEIND
BY LV:CAMPUSCD AS ''
BY LV:SSA AS '' IN +10
BY LV:LASTNAME AS ''
BY LS:LVPRD AS ''
BY TXT AS ''
BY LS:SSMOBAL AS '' FOLD-LINE
HEADING CENTER
"THE CALIFORNIA STATE UNIVERSITY"
"STATE SERVICE TRANSACTION INFORMATION"
"FOCEXEC(FOC1072)"
"REPORT RUN ON &DATE"
END
The following is only an excerpt from the actual report.
THE CALIFORNIA STATE UNIVERSITY
STATE SERVICE TRANSACTION INFORMATION
FOCEXEC(FOC1072)
REPORT RUN ON 99/99/99
SS
TRN PSN POST VOID VOID SRCE FRACT HRS DAYS TRANS RULE
TYP SEQ LS:LVPOSIT DATE IND DATE ID ORG AMT WKD WKD AMT IND
--- --- ---------- ---- ---- ---- --- --- ----- -- --- --- ---
000-00-0343 ELEPHANT 199501 STATE SVC: 1
BB 00 - - - 19950309 00000000 UX ONL .50000 .00 0 1
199502 STATE SVC: 2
FM 01 111-135-3300-029 19950313 00000000 LPR .50000 .00 0 0 3
CR 00 - - - 19950313 00000000 SYS .00000 .00 0 1
199503 STATE SVC: 3
FM 01 111-135-3300-029 19950412 00000000 LPR .50000 .00 0 0 3
CR 00 - - - 19950412 00000000 SYS .00000 .00 0 1
199504 STATE SVC: 4
FM 01 111-135-3300-029 19950511 00000000 LPR .50000 .00 0 0 3
CR 00 - - - 19950511 00000000 SYS .00000 .00 0 1
FOCEXEC: FOC1073
The report below prints employment history data for your employees. It uses the join between the LV file and the LH file to retrieve employee last name.
EX JLVLH
DEFINE FILE LV ADD
TEXT1/A20 = 'BEGIN LEAVE PERIOD:';
TEXT2/A18 = 'END LEAVE PERIOD:';
END
TABLE FILE LV
PRINT ALL.LH:LVPOSIT ALL.LH:EFFDATE ALL.LH:EFFEND ALL.LH:SEPCODE
ALL.LH:TIMEBASE ALL.LH:PAYFREQ ALL.LH:SALPER ALL.LH:CBID
ALL.LH:ROLLCODE ALL.LH:LVPRDST ALL.LH:LVPRDEND
BY LV:SSA AS '' IN +10
BY LV:LASTNAME AS ''
BY TEXT1 AS ''
BY ALL.LH:NPBGNLP AS '' IN +0
BY TEXT2 AS ''
BY ALL.LH:NPENDLP AS '' IN +0
ON LV:SSA SKIP-LINE
ON LH:NPENDLP FOLD-LINE
HEADING CENTER
"THE CALIFORNIA STATE UNIVERSITY"
"EMPLOYMENT HISTORY TRANSACTION INFORMATION"
"FOCEXEC(FOC1073)"
"REPORT RUN ON &DATE"
END
The following is only an excerpt from the actual report.
THE CALIFORNIA STATE UNIVERSITY
EMPLOYMENT HISTORY TRANSACTION INFORMATION
FOCEXEC(FOC1073)
REPORT RUN ON 99/99/99
BEGIN END TIME PAY SAL CB ROLL START END
LH:LVPOSIT DATE DATE STATUS BASE FREQ PER ID CODE LV PRD LV PRD
----------- ------ ---- ------ ---- ---- --- -- ---- ------ ------
000-00-0043 ELEPHANT BEGIN LEAVE PERIOD: 000000 END LEAVE PERIOD: 000000
166-228-3300-009 19950701 19950831 S 001002 M M M80 1 199507 199508
166-135-3300-029 19950101 19950630 001002 M M M80 1 199501 199506
000-00-0147 DEER BEGIN LEAVE PERIOD: 000000 END LEAVE PERIOD: 000000
166-107-3306-008 19970701 99999999 FT M M M80 1 199707 999999
166-107-3306-056 19941101 19970630 FT M M M80 1 199411 199706
000-00-0772 KANGAROO BEGIN LEAVE PERIOD: 000000 END LEAVE PERIOD: 000000
166-765-3306-008 19970701 99999999 FT M M M80 1 199707 999999
166-765-3306-036 19941101 19970630 FT M M M80 1 199411 199706
FOCEXEC: FOC1074
The following program prints all leave transaction data for your employees. It uses the join between the LV file and the LR file to retrieve employee last name.
EX JLVLR
TABLE FILE LV
PRINT ALL.LR:LVPOSIT ALL.LR:POST ALL.LR:VOIDIND ALL.LR:CBID
ALL.LR:TIMEBASE ALL.LR:TRANSSA ALL.LR:TRANLBID
BY LV:SSA AS '' IN +10
BY LV:LASTNAME AS ''
BY ALL.LV:POSIT16 AS ''
ON LV:POSIT16 FOLD-LINE
HEADING CENTER
"THE CALIFORNIA STATE UNIVERSITY"
"LEAVE TRANSACTION INFORMATION"
"FOCEXEC(FOC1074)"
"REPORT RUN ON &DATE"
END
The following is only an excerpt from the actual report.
THE CALIFORNIA STATE UNIVERSITY
LEAVE TRANSACTION INFORMATION
FOCEXEC(FOC1074)
REPORT RUN ON 99/99/99
TRAN
POST VOID CB TIME LB
LR:LVPOSIT DATE IND ID BASE LR:TRANSSA ID
---------- ---- ---- -- ---- ---------- --
000-00-0043 ELEPHANT 111-107-3305-008
111-107-3306-056 20030203 M80 FT 000-00-0000
111-107-3306-056 20030213 M80 FT 000-00-0000
111-107-3306-056 20030211 M80 FT 000-00-0000
FOCEXEC: FOC1075
The following program identifies employees who have taken Sick Leave - Family and/or Family Medical Leave. It uses the join between the LV file (Employee Specific Information) and the LR file to retrieve employee name.
EX JLVLR
DEFINE FILE LV ADD
FAMLV/A30 = IF (LR:LT EQ 'SL') AND (LR:TRANTYP EQ '02')
THEN 'SICK LEAVE USE - FAMILY' ELSE
IF LR:LT EQ 'FM' THEN 'FAMILY MEDICAL LEAVE'
ELSE 'OTHER';
END
TABLE FILE LV
HEADING CENTER
"THE CALIFORNIA STATE UNIVERSITY"
"FAMILY LEAVE USE"
"FOCEXEC(FOC1075)"
"REPORT RUN ON &DATE"
SUM LR:TRANAMT AS 'USED'
BY LV:WNAME AS 'EMPLOYEE'
BY LR:SSA AS 'SOCIAL'
BY LR:LVPRD AS 'LEAVE,PERIOD'
BY FAMLV AS 'LEAVE TYPE'
IF FAMLV NE OTHER
IF RECORDLIMIT EQ 50
ON LR:SSA SUBTOTAL MULTILINES AS 'TOTAL FOR:'
END
The following is only an excerpt from the actual report.
THE CALIFORNIA STATE UNIVERSITY
FAMILY LEAVE USE
FOCEXEC(FOC1075)
REPORT RUN ON 99/99/99
LEAVE
EMPLOYEE SOCIAL PERIOD LEAVE TYPE USED
-------- ------ ------ ---------- ----
ANTELOPE, MM 000-00-9526 199504 SICK LEAVE USE - FAMILY 1.000
199602 SICK LEAVE USE - FAMILY 1.000
199605 SICK LEAVE USE - FAMILY 3.000
199610 SICK LEAVE USE - FAMILY 8.000