Below are several sample FOCUS reports that use the JC file.
|
FOC1500
|
List Of Job Codes By Codes And Family
|
|
FOC1510
|
List Of MPP Employees And Job Titles, By SSA
|
|
FOC1520
|
Position Count By Job Code Using Systemwide Job Titles
|
Report Request: FOC1500
The following program is an example of using the JC file as a stand alone file.
DEFINE FILE JC ADD
DATE/A8=EDIT(JC:CHGDATE,'99/99/99');
LETTER1/A1=EDIT(JC:JOBCODE,'9$$$');
END
-*
TABLE FILE JC
HEADING CENTER
"THE CALIFORNIA STATE UNIVERSITY"
"LIST OF JOB CODES BY JOB CODE AND FAMILY"
"COMMON FOCEXEC: FOC1500"
"</1"
WHERE JC:CAMPUSCD EQ '50'
PRINT JC:JOBFAMLY AS 'JOB FAMILY TITLE:'
OVER JC:JOBFUNCT AS 'FUNCTIONAL AREA TITLE:'
OVER JC:JOBTITLE AS 'JOB CODE TITLE:'
OVER JC:JOBABBRV AS 'ABBREVIATED JOB CODE TITLE:'
OVER JC:AFFCODE AS 'AFFIRMATIVE ACTION CODE:'
OVER DATE AS 'DATE LAST CHANGED:'
BY JC:JOBCODE
BY JC:JOBFAMLY NOPRINT SKIP-LINE
-* IF LETTER1 EQ 'A' -THIS LINE MAY BE USED TO PRINT ALL JOB CODES
-* BEGINNING WITH 'A'
WHERE RECORDLIMIT EQ 10
END
The following is only an excerpt from the actual report.
THE CALIFORNIA STATE UNIVERSITY
LIST OF JOB CODES BY JOB CODE AND FAMILY
COMMON FOCEXEC: FOC1500
JOB CODE
--------
A013 JOB FAMILY TITLE: ADMINISTRATIVE AFFAIRS
FUNCTIONAL AREA TITLE: GENERAL ADMINISTRATION
JOB CODE TITLE: VICE PRESIDENT FOR ADMINISTRATION
ABBREVIATED JOB CODE TITLE: VP ADMINISTRATION
AFFIRMATIVE ACTION CODE: E0X
DATE LAST CHANGED: 01/06/95
A014 JOB FAMILY TITLE: ADMINISTRATIVE AFFAIRS
FUNCTIONAL AREA TITLE: GENERAL ADMINISTRATION
JOB CODE TITLE: ADVISOR TO THE PRESIDENT VP STUDENT AFFAIRS
ABBREVIATED JOB CODE TITLE: ADVISOR TO PRES & VPSA
AFFIRMATIVE ACTION CODE: P0X
DATE LAST CHANGED: 12/06/96
Report Request: FOC1510
The following program is an example for using the automatic join available between either the JC and AC files or the JC and SAC files. The join fields are Campus Code and Job Code.
EX AC
TABLE FILE AC
HEADING CENTER
"THE CALIFORNIA STATE UNIVERSITY"
"LIST OF MPP EMPLOYEES AND JOB TITLES, BY SSA"
"COMMON FOCEXEC: FOC1510"
"</1"
PRINT AC:WNAME AS 'NAME'
JC:JOBABBRV AS 'ABREVIATED,JOB CODE TITLE'
BY AC:SSA AS 'SSA'
WHERE AC:CBID EQ 'M80'
WHERE RECORDLIMIT EQ 10
END
The following is only an excerpt from the actual report.
THE CALIFORNIA STATE UNIVERSITY
LIST OF MPP EMPLOYEES AND JOB TITLES, BY SSA
COMMON FOCEXEC: FOC1510
ABBREVIATED
SSA NAME JOB CODE TITLE
--- ---- --------------
111-11-1111 SMITH, MICHAEL J ALUMNI AFFAIRS PRO 3
222-22-2222 RAMBIS, KURT K SW EXEC ADMIN SPPT PRO 3
333-33-3333 THORPE, OTIS L STUDENT ACAD SERV PRO 2
444-44-4444 KIRK, JIM T POLICE SERVICES ADM 2
999-99-9999 JOHNSON, JAY R OFF-CAMPUS PROG ADM 3
Report Request: FOC1520
The following program is an example of using the JC file with match logic.
EX AC
DEFINE FILE AC ADD
CNT/I6=1;
END
-*
MATCH FILE JC
PRINT JC:JOBABBRV
BY JC:JOBCODE AS JOBCODE
-* TO SELECT SYSTEMWIDE JOB TITLES
WHERE JC:CAMPUSCD EQ '00'
RUN
-*
FILE AC
SUM CNT
BY AC:JOBCODE AS JOBCODE
WHERE AC:CBID EQ 'M80'
AFTER MATCH HOLD AS PERMLRG
OLD-OR-NEW
END
-*
DEFINE FILE PERMLRG
USED/I6=IF CNT GT 0 THEN 1 ELSE 0;
END
-*
TABLE FILE PERMLRG
HEADING CENTER
"THE CALIFORNIA STATE UNIVERSITY"
"POSITION COUNT BY JOB CODE"
"USING SYSTEMWIDE JOB TITLES"
"COMMON FOCEXEC: FOC1520"
"</1"
PRINT JOBCODE AS 'JOB,CODE'
JC:JOBABBRV AS 'JOB TITLE'
CNT AS 'POSITION,COUNT'
USED AS 'TOTAL,USED'
-* TO EXCLUDE INVALID JOBCODES
WHERE JC:JOBABBRV NE ' '
WHERE RECORDLIMIT EQ 10
ON TABLE COLUMN-TOTAL
END
The following is only an excerpt from the actual report.
THE CALIFORNIA STATE UNIVERSITY
POSITION COUNT BY JOB CODE
USING SYSTEMWIDE JOB TITLES
COMMON FOCEXEC: FOC1520
JOB POSITION TOTAL
CODE JOB TITLE COUNT USED
---- --------- -------- -----
A011 ADMIN AFF GEN ADMIN ADM 1 3 1
A012 ADMIN AFF GEN ADMIN ADM 2 4 1
A013 ADMIN AFF GEN ADMIN ADM 3 16 1
A014 ADMIN AFF GEN ADMIN PRO 1 1 1
A015 ADMIN AFF GEN ADMIN PRO 2 1 1
A017 ADMIN AFF GEN ADMIN SUP 1 1 1
A019 ADMIN AFF GEN ADMIN SUP 3 0 0
A021 ADMIN AFF EXEC SPPT ADM 1 4 1
A022 ADMIN AFF EXEC SPPT ADM 2 14 1
A023 ADMIN AFF EXEC SPPT ADM 3 9 1
A024 ADMIN AFF EXEC SPPT PRO 1 12 1
A025 ADMIN AFF EXEC SPPT PRO 2 10 1
A026 ADMIN AFF EXEC SPPT PRO 3 5 1
TOTAL 89 12
Last Updated: February 1, 2000